### Select expressions

The Select expression is similar to an If expression. Sometimes however, you can write clearer and less repetitive formulas using the Select expression. For example, to evaluate the {Customer.Fax} field to determine if the area code is for Washington state (206, 360, 509) or British Columbia, Canada (604, 250):

    //Select example 1
    Select {Customer.Fax}[1 To 3]
       Case "604", "250" :
          "BC"
       Case "206", "509", "360" :
          "WA"
       Default :
          "";

The expression right after the Select keyword is called the Select condition. In the above example it is {Customer.Fax}[1 To 3]. The Select expression tries to find the first Case that matches the Select condition, and then executes the expression following the colon for that Case. The Default case is matched if none of the preceding cases match the Select condition. Notice that there is also a colon after the Default.

    //Same effect as Select example 1
    Local StringVar areaCode := {Customer.Fax}[1 To 3];
    If areaCode In ["604", "250"] Then
       "BC"
    Else If areaCode In ["206", "509", "360"] Then
       "WA"
    Else
       "";

##### Example

This formula groups the number of Oscar nominations a movie received into low, medium, high or extreme categories and in the process, shows some of the possibilities for the expression lists following the Case labels:

    //Select example 2
    Select {movie.NOM}
       Case 1,2,3, Is < 1 :
       (
          //Can have expression lists by using
          //parentheses
          10 + 20;
          "low"
       )
       Case 4 To 6, 7, 8, 9 :
          "medium"
       Case 10 :
          "high"
       Default :
          "extreme"

The Default clause of the Select expression is optional. If the Default clause is missing and none of the cases are matched, then the Select expression returns the default value for its expression type. For example, if in the above example the Default clause were omitted and {movie.NOM} = 11, it would return the empty string "". The Select expression is an expression, and similar comments as in the More details on If expressions section apply to it as well.

Seagate Software, Inc. http://www.seagatesoftware.com Please send comments to: techpubs@seagatesoftware.com